COMP::OmegaByte::Windows beállítások

Megosztás

• A Windows C meghajtó megosztásához nyissuk meg a //Sajátgép//et és kattintsunk jobb gombbal a C meghajtón.
• Nyissuk meg a //Tulajdonságok//at
• Navigáljunk a //Megosztás// fülre
• Írjuk át a "C$" megosztást "C"-re
• Mentsük el
• Készítsünk egy új felhasználót //FolderShare// néven, "12345" jelszóval
• A vezérlőpultban nyissuk meg a //"Mappa beállításai"// menüpontot
  • Válasszuk ki a //Nézet// fület
  • Kapcsoljuk ki az //"Egyszerű fájlmegosztás használata"// opciót
  • Mentsük el
• A C meghajtó tulajdonságaiban nyissuk meg a //"Biztonság"// fület, ami a mappa beállításainak mentését követően érhető el
• Adjuk hozzá a FolderShare felhasználót //Teljes// joggal és mentsük el.

Scriptek

Megosztás létrehozása

A script futtatásával egyszerűen beállíthatjuk a C mappa megosztását. A script végeztével lehet hozzá csatlakozni a FolderShare felhasználóval, "12345" jelszóval. A script elején konfigurációs szakasz található, ahol a felhasználónév, jelszó és a megosztott könyvtár szerkeszthető.

@echo off 

rem you can configure the PC with this params 

set SharedUserName=FolderShare
set SharedUserPassword=12345
set SharedFolderPath=C:
set SharedFolderName=C

rem end of configuration section

rem create user <SharedUserName> if does not exists

rem this command maybe print users on cli
net user | find /i "%SharedUserName%" || goto NoUserFound

:UserFound
echo User %SharedUserName% already exists
goto EndOfUser

:NoUserFound
echo Create user %SharedUserName% with password: %SharedUserPassword%
net user %SharedUserName% %SharedUserPassword% /ADD

:EndOfUser

rem End of user creation section

rem share folder with SAMBA

net share %SharedFolderName%=%SharedFolderPath%
if %ERRORLEVEL% EQU 0 (
 echo %SharedFolderPath% shared as %SharedFolderName%
) else (
 echo %SharedFolderName% already exists in system
)
rem End of shared folder section
rem grant access on <sharedFolder>
echo grant full permissions to %SharedUserName% on %SharedFolderPath%

cacls %SharedFolderPath%\ /e /g %SharedUserName%:f

rem end of grant access
pause